Sinds een aantal maanden is het mogelijk om formules te gebruiken in de lijstweergave. Deze krachtige functionaliteit geeft je de mogelijkheid om specifieke informatie voor je te laten berekenen. In dit artikel geven we je 12 handige formule voorbeelden. Let op: in de voorbeelden kunnen vrije velden zitten, die je zelf eerst moet aanmaken op je bord.

Hoeveel dagen tot de vervaldatum?

Met de volgende formule kun je het aantal resterende dagen zien tot de vervaldatum.

CONCATENATE(DAYS(field("CollectionDueDate"), TODAY()), " dagen")

Totale geschatte kosten berekenen

We gebruiken het veld Schatting (CardTime) en we vermenigvuldigen dit met het numerieke vrije veld Prijs per uur. De geschatte tijd is per minuut en de prijs is per uur, vandaar dat wij de uitkomst nog eens delen door 60. Uiteraard zijn ook gelijksoortige berekeningen mogelijk.

field("CardTime")*field("PrijsPerUur")/60

Geef aan of de vervaldatum "deze week", "volgende week" of "volgende maand" is

Met deze formule kun je snel zien of de vervaldatum er snel aankomt, of dat je nog even hebt.

IF((DAYS(field("CollectionDueDate"),TODAY())>30), "Volgende maand", 
IF((DAYS(field("CollectionDueDate"),TODAY())>14), "Deze maand", 
IF((DAYS(field("CollectionDueDate"),TODAY())>7), "Volgende week", "Deze week")))

Geef de specifieke dag van een datum aan

Wil je specifiek weten op welke dag van de week een datumveld is, kun je onderstaande formule gebruiken. In dit voorbeeld gebruiken we de startdatum van een kaartje.

IF(WEEKDAY(field("CardStart"))=1, "Zondag",
IF(WEEKDAY(field("CardStart"))=2, "Maandag", 
IF(WEEKDAY(field("CardStart"))=3, "Dinsdag",
IF(WEEKDAY(field("CardStart"))=4, "Woensdag", 
IF(WEEKDAY(field("CardStart"))=5, "Donderdag", 
IF(WEEKDAY(field("CardStart"))=6, "Vrijdag", 
IF(WEEKDAY(field("CardStart"))=7, "Zaterdag,","" )))))))

Percentage voortgang op basis van tijdregistratie

Met deze formule wordt de voortgang weergegeven van je tijdregistratie ten opzichte van je geschatte uren. Probeer onder de 100% te blijven :).

CONCATENATE(ROUND((field("CardTimeTracked") / field("CardTime") * 100),1), " %")

Bereken de leeftijd op basis van geboortedatum

Om snel inzicht te krijgen in leeftijden kun je onderstaande formule gebruiken. Handig in bijvoorbeeld HR gerelateerde borden, zoals werving en selectie.

CONCATENATE(ROUND(DIVIDE(DAYS(TODAY(),field("Geboortedatum")), 365),0), " jaar")

Geef tekstueel resultaat op basis van condities

Op basis van een numerieke waarde kun je resultaten weergeven. Stel voor dat je een score geeft voor een product sample. Op basis van deze score kun je een resultaat weergeven.

IF(field("Kwaliteitsscore")>80,"Excellent",
IF(field("Kwaliteitsscore")>50,"Goed",
IF(field("Kwaliteitsscore")>30,"Kan beter","Slecht")))

Bereken dimensionale gewicht of volume

Hebben je producten specifieke maten? Op basis van deze maten kun je de volume berekenen met onderstaande formule. In dit voorbeeld delen we de som door 6.000, dit is de standaard volume voor luchtvracht. Wegtransport is 3.000 en bij transport per zee geldt 1.000.

ROUND((field("Hoogte")*field("Breedte")*field("Lengte")/6000),2) & " kg"

Voortgang van je kaartjes door de statussen

Wil je inzichtelijk hebben hoever een kaartje door het aantal statussen is? Met onderstaande formule kun je dit mooi weergeven. Let op: je moet de naamgeving van de status exact benoemen.

IF(field("CardStatusName")="Open", "1/4", 
IF(field("CardStatusName")="In behandeling", "2/4", 
IF(field("CardStatusName")="Kwaliteitscontrole", "3/4", 
IF(field("CardStatusName")="Afgerond", "4/4",""))))

Laat het kwartaal zien waarin een datum valt

Met deze formule kun je snel zien in welk kwartaal een specifieke datum valt, bijvoorbeeld een vrij veld zoals leverdatum.

CONCATENATE("Q",ROUNDUP(MONTH(field("Leverdatum"))/3,0))

Bereken het aantal weken en dagen tussen twee datumvelden

Met de onderstaande formule krijg je snel in beeld wat het verschil in weken en dagen is tussen twee datumvelden.

ROUNDDOWN(DAYS(field("Leverdatum"),field("ProductieGereed"))/7,0)
&IF(ROUNDDOWN(DAYS(field("Leverdatum"),field("ProductieGereed"))/7,0)=1," week "," weken ")
&IF(MOD(DAYS(field("Leverdatum"),field("ProductieGereed")),7)=0,"",
"& "&MOD(DAYS(field("Leverdatum"),field("ProductieGereed")),7)&" dagen")

Laat zien of een vervaldatum is overschreden

Laat tekstueel zien of een vervaldatum is overschreden met onderstaande formule. Je kan hier bijvoorbeeld ook emoticons gebruiken.

IF(DAYS(field("CollectionDueDate"),TODAY())>0,"😀","❗️")

Wil je meer weten over formules bekijk dan ons helpcenter. Een ding is zeker. Op vPlan kun je rekenen!

Heb jij nog geen vPlan? Maak hier dan een gratis account aan voor 14 dagen.